Programm beenden

[xtend]

Hallo!

Ich suche eine Möglichkeit, mit VBS Anwendungen zu beenden.

Ich muss zwei Batch-Dateien und dann den Internet-Explorer starten (mache ich mit WScrip.run und beim IE mit true am schluss), wenn der IE beendet wird, sollen die zwei Batch-Dateien auch beendet werden. Wie funktioniert das?

Und wie kann ich mit VBS in ein Dos-Fenster hineinschreiben?

vielen dank für die antworten

david

[dieseyer]

Hallo!

Nachdem du http://dieseyer.de/dse-wsh-scr-b.html#progstrt gelesen (und verstanden) hast, kannst du es so machen:

Set ProgBat1 = WshShell.Exec( "erste.bat")
Set ProgBat2 = WshShell.Exec( "zweite.bat")

mit .Run (und true) den IE starten
(wenn der IE beendet ist)

Set ProgBat1 = nothing
Set ProgBat2 = nothing

[Chäsi]

Set ProgBat1 = WshShell.Exec( "erste.bat")
Set ProgBat2 = WshShell.Exec( "zweite.bat")

mit .Run (und true) den IE starten
(wenn der IE beendet ist)

Set ProgBat1 = nothing
Set ProgBat2 = nothing

hm... das geht bei mir nit! Es gibt zwar keinen Fehler aus, aber das Programm beendet nicht, wenn ich ihm nothing zuweise

Zur Info: Ich hab ein eigenes kleines VB-Programm geschrieben, das nur Infos ausgibt. Keine Schliess-Buttons oder so was!

Hat einer ne Idee, wie ich das beenden könnte?

mfg Chäsi

[James Blond]

Da gibt es 3 Möglichkeiten

1. Unload Me 'aktuelle Form schließen
2. Me.Hide 'aktuelle Form verstecken
3 End 'aktuelles Programm beenden

Du hast die Wahl.

[Chäsi]

sorry, du hast mich glaub ich falsch verstanden. Nicht das Programm soll sich selber beenden sondern das VB-Script soll das Programm beenden...

[James Blond]

Ab und an hilft es den "kleinen" großen Link Search auf der Seite zu benutzen, dann hättest Du folgendes gefunden

http://www.source-center.de/board/viewtopic.php?t=1590

Dort gibt es eine Antwort.

set wmi = GetObject("winmgmts:") 
set system = wmi.instancesOf("win32_process") 
for each process in system 
  if lcase(process.name)="DeinProgg.exe" then 
    process.Terminate (0) 
  end if 
next

[dieseyer]

Hallo!

WER hat denn den Müll geschrieben:

Set ProgBat1 = nothing
Set ProgBat2 = nothing

Richtig muss es heißen:

ProgBat2.Terminate
ProgBat1.Terminate

Mehr dazu: http://dieseyer.de/dse-wsh-scr-b.html#exec

[Chäsi]

Danke Jungs, mit terminate funktioniert es wunderbar

mfg Chäsi


PS: @ James Blond
hab schon gesucht, aber nix gefunden

[James Blond]

' notepadkiller.vbs
' Beendet alle Instanzen von Notepad
' (C) Tobias Weltner, c't 13/2001

' mit WMI verbinden
on error resume next
set wmi = GetObject("winmgmts:")
if err.number<>0 then
  MsgBox "WMI nicht installiert!"
  WScript.Quit
end if
on error goto 0

' Anfrage formulieren
wql = "select * from win32_process"

' Absenden
set ergebnis = wmi.ExecQuery(wql)

' Auswerten
for each objekt in ergebnis
  liste = liste & objekt.name & " Prozess-ID: " & objekt.processID & vbCr
next


WScript.Echo "Liste aller Prozesse:" & vbCr & liste
MsgBox "Beende nun alle Notepad-Instanzen!"

wql = "select * from win32_process where name='notepad.exe'"
set ergebnis = wmi.ExecQuery(wql)

counter = 0
for each notepad in ergebnis
  counter = counter + 1
  notepad.Terminate 0
next

MsgBox "Habe " & counter & " Notepads geschlossen!"

[SmokyMcPot]

set wmi = GetObject("winmgmts:") 
set system = wmi.instancesOf("win32_process") 
for each process in system 
if lcase(process.name)="DeinProgg.exe" then 
process.Terminate (0) 
end if 
next

-> Der hervorgehobene Teil muss klein geschrieben werden, sonst wird der Prozess nicht gefunden.